Документ взят из кэша поисковой машины. Адрес оригинального документа : http://mirror.msu.net/pub/gentoo-portage/net-p2p/bitcoind/bitcoind-0.12.0.ebuild Дата изменения: Thu Mar 24 22:36:33 2016 Дата индексирования: Mon Apr 11 08:39:24 2016 Кодировка:

# Copyright 2010-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

BITCOINCORE_COMMITHASH="188ca9c305d3dd0fb462b9d6a44048b1d99a05f3"
BITCOINCORE_LJR_DATE="20160226"
BITCOINCORE_LJR_PREV="rc1"
BITCOINCORE_IUSE="examples ljr test upnp +wallet zeromq"
BITCOINCORE_POLICY_PATCHES="+rbf spamfilter"
BITCOINCORE_NEED_LEVELDB=1
BITCOINCORE_NEED_LIBSECP256K1=1
inherit bash-completion-r1 bitcoincore user systemd

DESCRIPTION="Original Bitcoin crypto-currency wallet for automated services"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~x86 ~amd64-linux ~x86-linux"

pkg_setup() {
local UG='bitcoin'
enewgroup "${UG}"
enewuser "${UG}" -1 -1 /var/lib/bitcoin "${UG}"
}

src_prepare() {
sed -i 's/have bitcoind &&//;s/^\(complete -F _bitcoind bitcoind\) bitcoin-cli$/\1/' contrib/${PN}.bash-completion || die
bitcoincore_src_prepare
}

src_configure() {
bitcoincore_conf \
--with-daemon
}

src_install() {
bitcoincore_src_install

insinto /etc/bitcoin
newins "${FILESDIR}/bitcoin.conf" bitcoin.conf
fowners bitcoin:bitcoin /etc/bitcoin/bitcoin.conf
fperms 600 /etc/bitcoin/bitcoin.conf

newconfd "contrib/init/bitcoind.openrcconf" ${PN}
newinitd "contrib/init/bitcoind.openrc" ${PN}
systemd_dounit "${FILESDIR}/bitcoind.service"

keepdir /var/lib/bitcoin/.bitcoin
fperms 700 /var/lib/bitcoin
fowners bitcoin:bitcoin /var/lib/bitcoin/
fowners bitcoin:bitcoin /var/lib/bitcoin/.bitcoin
dosym /etc/bitcoin/bitcoin.conf /var/lib/bitcoin/.bitcoin/bitcoin.conf

dodoc doc/assets-attribution.md doc/bips.md doc/tor.md
doman contrib/debian/manpages/{bitcoind.1,bitcoin.conf.5}

use zeromq && dodoc doc/zmq.md

newbashcomp contrib/${PN}.bash-completion ${PN}

if use examples; then
docinto examples
dodoc -r contrib/{qos,spendfrom,tidy_datadir.sh}
use zeromq && dodoc -r contrib/zmq
fi

insinto /etc/logrotate.d
newins "${FILESDIR}/bitcoind.logrotate-r1" bitcoind
}